Comment puis-je forcer nos développeurs à entrer dans des notes lors de la commission via Tortoisesvn?

Bien sûr, mais comment allez-vous faire respecter des messages de validation non gibbacs, significatifs et contextualisés?

Mieux vaut simplement frapper vos collègues irresponsables lorsque vous remarquez un commit boiteux / vide. Ou l'équivalent verbal du poinçon. Assurez-vous simplement qu'ils se sentent mal, il est mérité.

Vous pouvez définir un script de crochet de pré-validation qui rejette tous les engagements avec un message de journal vide ou trop court.

Voici un post sur la façon de le faire.

J'ai utilisé un script de crochet de pré-validation pour vous assurer qu'un commentaire de commettre fait toujours référence à un numéro de numéro dans le système de suivi des émissions. Par exemple, un commentaire tel que

fixes frobulator when the moon is full (bug 1234)

Notre crkscript de pré-validation (Windows Batch):

@echo off & setlocal ENABLEEXTENSIONS

set SVNLOOK="E:\Subversion\Program\Subversion 1.5.0\bin\svnlook.exe"

set REPOS=%1%
set TXN=%2%
set LOGFILE=%REPOS%\hooks\log-%TXN%.txt
set GREP=E:\UnxUtils\usr\local\wbin\grep.exe

%SVNLOOK% log -t "%TXN%" "%REPOS%" >%LOGFILE%

set "first="
for /f "delims=" %%a in ('more ^< "%LOGFILE%"') do (
  if not defined first set first=%%a
)

del %LOGFILE%

if not defined first ( echo "Please supply a commit comment" >&2 & exit 1 )





REM Check for invalid windows characters in the path
echo Checking >%LOGFILE%
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | find "\" >>%LOGFILE%
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | find ":" >>%LOGFILE%
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | find "*" >>%LOGFILE%
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | find "?" >>%LOGFILE%
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | find """" >>%LOGFILE%
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | find "^>" >>%LOGFILE%
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | find "^<" >>%LOGFILE%
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | find "^|" >>%LOGFILE%

set "first="
for /f "delims=" %%a in ('more +1 ^< "%LOGFILE%"') do (
  if not defined first set first=%%a
)

del %LOGFILE%

if defined first ( echo "Please do not use filename characters which are invalid in  windows. - Found %first%" >&2 & exit 1 )






REM Tagblock - prevent changes to tag directories
echo Checking >%LOGFILE%
%SVNLOOK% changed -t "%TXN%" "%REPOS%" | %GREP% "^U.*\/tags\/.*" | %GREP% -v -f "%REPOS%\conf\tag-block-exceptions.txt" >>%LOGFILE%

set "first="
for /f "delims=" %%a in ('more +1 ^< "%LOGFILE%"') do (
  if not defined first set first=%%a
)

del %LOGFILE%


if defined first ( 
    echo "%first% -- Error: Modifications to tag directories are blocked. To allow these modifications add the path to %REPOS%\conf\tag-block-exceptions.txt" >&2 
    exit 1 )

Pas de tortuevn, mais Subversion elle-même - un paramètre sur le serveur. Vous pouvez créer un crochet de pré-validation qui applique un commentaire commettre. Il existe également des crochets de pré-validation qui vérifieront la présence d'une référence à un système de suivi des problèmes comme Jira si vous souhaitez aller plus loin.

Tortoisesvn est un client, vous voudrez peut-être Force commente sur le serveur Subversion . Ou vous pouvez leur dire de commenter leurs engagements.

Vous devez utiliser un crochet de pré-validation qui est un paramètre de serveur, j'ai écrit un pour VisualSvn, qui est fondamentalement un fichier de parquet - des scripts similaires sont disponibles pour les serveurs SVN basés sur des fenêtres.

@echo off
::
:: Stops commits that have empty log messages.
::
@echo off
setlocal

rem Subversion sends through the path to the repository and transaction id
set REPOS=%1
set TXN=%2

rem check for an empty log message
call "C:\program files\visualsvn server\bin\svnlook" log %REPOS% -t %TXN% | findstr . > nul
if %errorlevel% gtr 0 (goto err) else exit 0

:err
echo. 1>&2
echo Your commit has been blocked because you didn't give any log message 1>&2
echo Please write a log message describing the purpose of your changes and 1>&2
echo then try committing again. -- Thank you 1>&2
exit 1

Vous pouvez forcer une commenter facilement suffisamment, mais ce que vous finirez avec un million de commits qui disent "débogage" ou "test".

Si vos développeurs ne voient pas la valeur dans l'ajout de messages de validation les forcer à taper quelque chose ne va pas changer cela.

Ce qui est pire, c'est lorsque les utilisateurs d'Eclipse ont une SVN / CVS intégré de manière à ce qu'il se souvienne de leur dernier message de validation - et ils finissent par commettre un fichier entièrement indépendant avec le message de leur dernière tâche / projet.