Diffs de cas insensible au Mercurial

Voici la solution que j'ai installée. C'est loin d'être idéal, mais mieux que les autres alternatives que j'ai envisagées.

J'ai créé un script Autohotkey qui suit: p>

• revertit les fichiers d'accès MS dans un référentiel avec des modifications détectées (fichiers .orig) li>
• se lit dans le fichier .orig (celui avec les modifications) li>
• se lit dans le fichier existant (celui déjà dans le référentiel) li>
• convertit le texte des deux fichiers en minuscule li>
• compare le contenu des fichiers minuscules des fichiers li>
• Si les fichiers diffèrent toujours, le fichier .orig est restauré afin que cela puisse être attaché au référentiel li>
• Si les fichiers sont les mêmes (c'est-à-dire qu'ils ne diffèrent que dans le cas où le fichier .orig est supprimé car nous ne nous soucions pas de ces changements) li> ul>

  pour les fichiers qui ont des changements réels que nous nous soucions, je vois toujours les changements de cas qui ont été apportés. Si cela entraîne beaucoup de bruit, j'ouvre le fichier dans un outil de comparaison qui permet à la casse-insensitante se compare (par exemple, KDiff). P>

  Ce n'est pas une solution parfaite, mais elle supprime environ 90% de la Frustration pour moi. P>

  Voici mon script. Notez que le script comprend un autre script Autohotkey, ConsoleAppaT.ahk, qui fournit une fonction nommée, consoleApp_Runwait () code>. Ceci est un script tiers qui ne fonctionne plus très bien avec 64 bits AHK, alors je ne comprends pas cela dans le cadre de ma réponse. Toute fonction AHK qui exécute une ligne de commande et renvoie la sortie en tant que chaîne suffira. P>

  ; This script checks an MS Access source directory and reverts all files whose only modifications are to the 
  ; case of the characters within the file.
  
  #Include %A_ScriptDir%\ConsoleApp.ahk
  #NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
  SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
  SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.
  
  ; Allow for custom path to hg (support for moving to TortoiseHg 2.0)
  IniRead hg, %A_ScriptDir%\LocalSettings\Settings.cfg, TortoiseHg, hg_path, hg
  
  if 0 < 1  ; The left side of a non-expression if-statement is always the name of a variable.
  {
      MsgBox Usage:`n`HgIgnoreCase DirectoryWithFilesToScrub
      ExitApp
  }
  
  SrcDir = %1%
  StringReplace SrcDir, SrcDir, ", , All
  
  StringRight test, SrcDir, 1 ; add trailing slash if necessary
  ifnotequal test, \
      SrcDir = %SrcDir%\
  
  RestoreOriginals(SrcDir)
  RevertCaseChangeModifiedFiles(SrcDir)
  
  RevertCaseChangeModifiedFiles(SrcDir) {
  global hg
      includes =  -I "*.form" -I "*.bas" -I "*.report" -I "*.table"
      cmdline = %hg% revert --all %includes%
  
      ;Don't revert items that have been removed completely
      Loop 3
      {
          Result := ConsoleApp_RunWait(hg . " status -nrd " . includes, SrcDir)
          If (Result)
              Break
      }
      Loop parse, Result, `n, `r
      {
          if (A_LoopField)
              cmdline = %cmdline% -X "%A_LoopField%"
      }
      Result =
      ;msgbox %cmdline%
      ;revert all modified forms, reports, and code modules
      Loop 3
      {
  
          Result := ConsoleApp_RunWait(cmdline, SrcDir)
          If (Result)
              Break
      }
      ;MsgBox %Result%
  
      Loop parse, Result, `n, `r
      {
          StringLeft FileStatus, A_LoopField, 9
          If (FileStatus = "reverting")
          {
              StringMid FName, A_LoopField, 11
              FullPath = %SrcDir%%FName%
              ToolTip Checking %FullPath%
              RestoreIfNotEqual(FullPath, FullPath . ".orig")
          }
      }
      ToolTip
  }
  
  RestoreIfNotEqual(FName, FNameOrig) {
      FileRead File1, %FName%
      FileRead File2, %FNameOrig%
  
      StringLower File1, File1
      StringLower File2, File2
      ;MsgBox %FName%`n%FNameOrig%
      If (File1 = File2)
          FileDelete %FNameOrig%
      Else
          FileMove %FNameOrig%, %FName%, 1
  }
  
  RestoreOriginals(SrcDir) {
      Loop %SrcDir%*.orig
      {
          ;MsgBox %A_LoopFileLongPath%`n%NewName%
          NewName := SubStr(A_LoopFileLongPath, 1, -5)
          FileMove %A_LoopFileLongPath%, %NewName%, 1
      }
      while FileExist(SrcDir . "*.orig")
          Sleep 10
  }