Gratter la date actuelle du site Web à l'aide d'Excel VBA

si vous avez besoin de Lunes, 19 de août 2019 , utilisez getElementById pour fecha

Debug.Print IE.document.getElementById("fecha").Innerhtml

Bien que la réponse donnée par @Siddharth Rout soit parfaitement correcte, il faudrait un peu de manipulation de chaîne pour obtenir la date sous une forme utilisable.

Pour la raison ci-dessus, je propose une solution alternative qui obtient le date dans un format directement utilisable, prêt à être manipulé et utilisé dans d'autres calculs si nécessaire.

En prime, je montre comment obtenir la date en utilisant une requête HTTP au lieu d'utiliser Internet Explorer. Cela rend le code plus efficace.

Option Explicit

Sub getDate()
Dim req As New WinHttpRequest
Dim doc As New HTMLDocument
Dim el As HTMLParaElement
Dim key As String
Dim url As String
Dim retrievedDate As Date
url = "http://www.fechadehoy.com/venezuela"
key = "Fecha actual: "

''''''''''Bonus: Use an HTTP request to get the date instead of opening IE'''''''''''
With req                                                                            '
    .Open "GET", url, False                                                         '
    .send                                                                           '
    doc.body.innerHTML = .responseText                                              '
    'Debug.Print .responseText                                                       '
End With                                                                            '
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

For Each el In doc.getElementsByTagName("p")
    If el.innerText Like "Fecha actual*" Then
        retrievedDate = Mid(el.innerText, InStr(el.innerText, key) + Len(key), Len(el.innerText))
    End If
Next el

End Sub

Vous devrez ajouter une référence à Microsoft HTML Object Library et Microsoft WinHTTP Services version 5.1 . Pour ce faire, allez dans l'éditeur VB> Outils> Références.

Avoir la date dans ce format signifie qu'elle peut être facilement manipulée. Un exemple serait l'utilisation de fonctions telles que jour (retrievedDate) , mois (retrievedDate) , année (retrievedDate) etc.

Pourquoi opter pour IE alors que xhr peut faire l'affaire? Vous pouvez obtenir la date en un clin d'œil si vous optez pour XMLHttpRequest.

Sub GetCurrentDate()
    Dim S$

    With CreateObject("MSXML2.XMLHTTP")
        .Open "GET", "http://www.fechadehoy.com/venezuela", False
        .send
        S = .responseText
    End With

    With CreateObject("htmlfile")
        .body.innerHTML = S
        MsgBox .getElementById("fecha").innerText
    End With
End Sub

Référence à ajouter:

Microsoft XML, v6.0
Microsoft HTML Object Library