Plusieurs événements Worksheet_Change dans le code vba

Comme ça, vous pouvez faire les deux choses dans le même événement

Vous devez ajouter Application.EnableEvents = False au début pour éviter la condition de concurrence.

Private Sub Worksheet_Change(ByVal Target As Range)
 Application.EnableEvents = False

    Dim ccr As Range, acr as Range

    Set ccr = Range("C6")
    For Each Cell In ccr
      Cell.Value = LCase(Cell)
    Next Cell

    Set acr = Range("C9:G9")
    For Each Cell In acr
      Cell.Value = LCase(Cell)
    Next Cell
 Application.EnableEvents = True

End Sub

Le problème principal est que la modification d'une valeur de cellule Cell.Value déclenchera immédiatement un autre Worksheet_Change . Vous devez Application.EnableEvents = False pour éviter cela.

Je recommande également de travailler avec Intersect pour que le code ne fonctionne que sur les cellules qui sont réellement modifiées.

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim AffectedRange As Range
    Set AffectedRange = Intersect(Target, Target.Parent.Range("C6, C9:G9"))

    Application.EnableEvents = False 'pervent triggering another change event
    On Error GoTo ERR_HANDLING

    If Not AffectedRange Is Nothing Then
        Dim Cel As Range
        For Each Cel In AffectedRange.Cells
            Cel.Value = LCase$(Cel.Value)
        Next Cel
    End If

    On Error GoTo 0

    'no Exit Sub here!
ERR_HANDLING:
    Application.EnableEvents = True 

    If Err.Number <> 0 Then
        Err.Raise Err.Number, Err.Source, Err.Description, Err.HelpFile, Err.HelpContext
    End If
End Sub

En plus du commentaire de @Frank Ball, y compris la gestion des erreurs:

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim AffectedRange As Range
    Set AffectedRange = Intersect(Target, Target.Parent.Range("C6, C9:G9"))

    If Not AffectedRange Is Nothing Then
        Application.EnableEvents = False 'pervent triggering another change event

        Dim Cel As Range
        For Each Cel In AffectedRange.Cells
            Cel.Value = LCase$(Cel.Value)
        Next Cel

        Application.EnableEvents = True 'don't forget to re-enable events in the end
    End If
End Sub

Les deux événements Worksheet_Change sont assez identiques, ils sont une boucle autour d'une plage, renvoyant LCase () . Ainsi, c'est une bonne idée de créer un Sub séparé pour lui comme ceci:

Private Sub Worksheet_Change(ByVal Target As Range)

    If Not Intersect(Target, Range("C6"), Range("C9:G9")) Is Nothing Then Exit Sub
    Application.EnableEvents = False
    FixRangeLCase Range("C6")
    FixRangeLCase Range("C9:G9")
    Application.EnableEvents = True

End Sub

Ensuite, faites-lui référence à l'événement Worksheet_Change. Dans la mesure où l'événement Worksheet_Change est assez "cher", en cours d'exécution toujours, il est judicieux de ne l'exécuter que lorsqu'une cellule cible spécifique est modifiée et sinon quittez la procédure - If Intersect ( Target, Range ("C6"), Range ("C9: G9")) Is Nothing Then Exit Sub

Le Application.EnableEvents = False est nécessaire pour désactiver les événements. À la fin, il est remis à Vrai .

Sub FixRangeLCase(rangeToFix As Range)        
    Dim myCell As Range
    For Each myCell In rangeToFix
        myCell.Value2 = LCase(myCell.Value2)
    Next myCell    
End Sub

Vous pouvez également utiliser:

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)

    Dim rng As Range, cell As Range

    Application.EnableEvents = False

        If Not Intersect(Target, Range("C6")) Is Nothing Or Not Intersect(Target, Range("C9:G9")) Is Nothing Then
            Set rng = Range("C9:G9", "C6")

            For Each cell In rng
                cell.Value = LCase(cell.Value)
            Next
        End If

    Application.EnableEvents = True

End Sub